plugins {
	id 'com.android.application'
}

ext.vvl_version='1.4.321.0'
apply from: "./download_vvl.gradle"

android {
	ndkVersion '28.2.13676358'
	compileSdk 35

	defaultConfig {
		applicationId 'com.khronos.vulkan_samples'
	namespace "com.khronos.vulkan_samples"
		minSdk 30
		targetSdk 35
		versionCode 1
		versionName "1.0"

		externalNativeBuild {
			cmake {
				abiFilters.addAll( 'arm64-v8a' )
				arguments '-DANDROID_TOOLCHAIN=clang', '-DANDROID_STL=c++_static', '-DVKB_VALIDATION_LAYERS=OFF'
			}
		}
	}

	buildTypes {
		debug {
			debuggable true
			jniDebuggable true
		}

		release {
			minifyEnabled false
			proguardFiles getDefaultProguardFile('proguard-android-optimize.txt')
			signingConfig debug.signingConfig
		}
		applicationVariants.all{variant ->
			variant.outputs.each{output->
                def tempName = output.outputFile.name
                tempName = tempName.replace("app-", "vulkan_samples-")
                output.outputFileName  = tempName
			}
        }
	}

	compileOptions {
		sourceCompatibility JavaVersion.VERSION_21
		targetCompatibility JavaVersion.VERSION_21
	}

	sourceSets {
		main {
			
			res.srcDirs += [ '../../app/android/res' ]
			java.srcDirs += [ '../../app/android/java' ]
			
			manifest.srcFile '../../app/android/AndroidManifest.xml'
		}
	}

	externalNativeBuild {
		cmake {
			version "3.22.1"
			path '../../CMakeLists.txt'
			buildStagingDirectory 'build-native'
		}
	}

	lint {
		abortOnError false
		checkReleaseBuilds false
	}
	
	buildFeatures {
		viewBinding true
		prefab true
	}
}

dependencies {
	implementation 'androidx.appcompat:appcompat:1.7.0'
	implementation 'com.google.android.material:material:1.12.0'
	implementation 'androidx.constraintlayout:constraintlayout:2.2.0'
	implementation 'androidx.core:core:1.15.0'
	implementation 'androidx.games:games-activity:3.0.5'
}