init

shaders/dynamic_line_rasterization/hlsl/base.frag.hlsl

@@ -0,0 +1,32 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSOutput
+{
+    float4 Pos : SV_POSITION;
+};
+
+struct PushConstants
+{
+    float4 color;
+};
+[[vk::push_constant]] PushConstants pushConstant;
+
+float4 main(VSOutput input) : SV_TARGET0
+{
+    return pushConstant.color;
+}

shaders/dynamic_line_rasterization/hlsl/base.vert.hlsl

@@ -0,0 +1,42 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+};
+
+struct UBO
+{
+    float4x4 projection;
+    float4x4 view;
+    float4x4 model;
+};
+[[vk::binding(0, 0)]]
+ConstantBuffer<UBO> ubo : register(b0);
+
+struct VSOutput
+{
+    float4 Pos : SV_POSITION;
+};
+
+VSOutput main(VSInput input)
+{
+    VSOutput output = (VSOutput) 0;
+    output.Pos = mul(ubo.projection, mul(ubo.view, mul(ubo.model, float4(input.Pos - float3(0.0f, 1.0f, 0.0f), 1.0))));
+    return output;
+}

shaders/dynamic_line_rasterization/hlsl/grid.frag.hlsl

@@ -0,0 +1,62 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSOutput
+{
+    float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 nearPoint : VECTOR0;
+[[vk::location(1)]] float3 farPoint : VECTOR1;
+[[vk::location(2)]] float4x4 view : MATRIX0;
+[[vk::location(6)]] float4x4 projection : MATRIX1; 
+};
+
+float4 grid(float3 pos) {
+    float2 coord = pos.xz;
+    float2 derivative = fwidth(coord);
+    float2 grid = abs(frac(coord - 0.5) - 0.5) / derivative;
+    float _line = min(grid.x, grid.y);
+    float minimumz = min(derivative.y, 1);
+    float minimumx = min(derivative.x, 1);
+    float4 color = float4(0.5, 0.5, 0.5, 1.0 - min(_line, 1.0));
+
+    if(abs(pos.x) < minimumx)
+        color.y = 1;
+    if(abs(pos.z) < minimumz)
+        color.x = 1;
+    return color;
+}
+
+float fadeFactor(float3 pos, VSOutput input) {
+    float z = mul(input.projection, mul(input.view, float4(pos.xyz, 1.0))).z;
+    // Empirical values are used to determine when to cut off the grid before moire patterns become visible.
+    return z * 6 - 0.5;
+}
+
+float4 main(VSOutput input) : SV_TARGET0
+{
+    float t = -input.nearPoint.y / (input.farPoint.y - input.nearPoint.y);
+    float3 pos = input.nearPoint + t * (input.farPoint - input.nearPoint);
+
+    // Display only the lower plane
+    if(t < 1.0) {
+        float4 gridColor = grid(pos);
+        return float4(gridColor.xyz, gridColor.w * fadeFactor(pos, input));
+    }
+    else {
+        return float4(0.0, 0.0, 0.0, 0.0);
+    }
+}

shaders/dynamic_line_rasterization/hlsl/grid.vert.hlsl

@@ -0,0 +1,64 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+ struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+};
+
+struct UBO
+{
+    float4x4 projection;
+    float4x4 view;
+    float4x4 model;
+    float4x4 viewProjectionInverse;
+};
+[[vk::binding(0, 0)]]
+ConstantBuffer<UBO> ubo : register(b0);
+
+struct VSOutput
+{
+    float4 Pos : SV_POSITION;
+[[vk::location(0)]] float3 nearPoint : VECTOR0;
+[[vk::location(1)]] float3 farPoint : VECTOR1;
+[[vk::location(2)]] float4x4 view : MATRIX0;
+[[vk::location(6)]] float4x4 projection : MATRIX1;
+};
+
+float3 unprojectPoint(float x, float y, float z, float4x4 viewProjectionInverse) {
+    float4 clipSpacePos = float4(x, y, z, 1.0);
+    float4 eyeSpacePos = mul(viewProjectionInverse, clipSpacePos);
+    return eyeSpacePos.xyz / eyeSpacePos.w;
+}
+
+static float3 gridPlane[6] = {
+    float3(1, 1, 0), float3(-1, -1, 0), float3(-1, 1, 0),
+    float3(-1, -1, 0), float3(1, 1, 0), float3(1, -1, 0)
+};
+
+VSOutput main(VSInput input, uint VertexIndex : SV_VertexID)
+{
+    float3 pos = gridPlane[VertexIndex].xyz;
+
+    VSOutput output = (VSOutput) 0;
+    output.nearPoint = unprojectPoint(pos.x, pos.y, 0.0, ubo.viewProjectionInverse);
+    output.farPoint = unprojectPoint(pos.x, pos.y, 1.0, ubo.viewProjectionInverse);
+    output.view = ubo.view;
+    output.projection = ubo.projection;
+    output.Pos = float4(pos, 1.0);
+    return output;
+}