init

2025-09-04 10:54:47 +08:00
commit 6bc8f61b18
1808 changed files with 208268 additions and 0 deletions
@@ -0,0 +1,77 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+Texture2D textureColor0 : register(t0);
+SamplerState samplerColor0 : register(s0);
+Texture2D textureColor1 : register(t1);
+SamplerState samplerColor1 : register(s1);
+
+[[vk::constant_id(0)]] const int dir = 0;
+
+float4 main([[vk::location(0)]] float2 inUV : TEXCOORD0) : SV_TARGET
+{
+	// From the OpenGL Super bible
+	const float weights[] = {	0.0024499299678342,
+								0.0043538453346397,
+								0.0073599963704157,
+								0.0118349786570722,
+								0.0181026699707781,
+								0.0263392293891488,
+								0.0364543006660986,
+								0.0479932050577658,
+								0.0601029809166942,
+								0.0715974486241365,
+								0.0811305381519717,
+								0.0874493212267511,
+								0.0896631113333857,
+								0.0874493212267511,
+								0.0811305381519717,
+								0.0715974486241365,
+								0.0601029809166942,
+								0.0479932050577658,
+								0.0364543006660986,
+								0.0263392293891488,
+								0.0181026699707781,
+								0.0118349786570722,
+								0.0073599963704157,
+								0.0043538453346397,
+								0.0024499299678342};
+
+
+	const float blurScale = 0.003;
+	const float blurStrength = 1.0;
+
+	float ar = 1.0;
+	// Aspect ratio for vertical blur pass
+	if (dir == 1)
+	{
+		float2 ts;
+		textureColor1.GetDimensions(ts.x, ts.y);
+		ar = ts.y / ts.x;
+	}
+
+	float2 P = inUV.yx - float2(0, (25 >> 1) * ar * blurScale);
+
+	float4 color = float4(0.0, 0.0, 0.0, 0.0);
+	for (int i = 0; i < 25; i++)
+	{
+		float2 dv = float2(0.0, i * blurScale) * ar;
+		color += textureColor1.Sample(samplerColor1, P + dv) * weights[i] * blurStrength;
+	}
+
+	return color;
+}
@@ -0,0 +1,30 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float2((VertexIndex << 1) & 2, VertexIndex & 2);
+	output.Pos = float4(output.UV * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}
@@ -0,0 +1,32 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+Texture2D textureColor0 : register(t0);
+SamplerState samplerColor0 : register(s0);
+Texture2D textureColor1 : register(t1);
+SamplerState samplerColor1 : register(s1);
+
+struct VSOutput
+{
+    float4 Pos : SV_POSITION;
+    [[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+float4 main(VSOutput input) : SV_TARGET
+{
+	return textureColor0.Sample(samplerColor0, input.UV);
+}
@@ -0,0 +1,30 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+};
+
+VSOutput main(uint VertexIndex : SV_VertexID)
+{
+	VSOutput output = (VSOutput)0;
+	output.UV = float2((VertexIndex << 1) & 2, VertexIndex & 2);
+	output.Pos = float4(output.UV * 2.0f - 1.0f, 0.0f, 1.0f);
+	return output;
+}
@@ -0,0 +1,79 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+Texture2D textureEnvMap : register(t1);
+SamplerState samplerEnvMap : register(s1);
+
+struct VSOutput
+{
+float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+struct FSOutput
+{
+	float4 Color0 : SV_TARGET0;
+	float4 Color1 : SV_TARGET1;
+};
+
+struct PushConstants
+{
+	float4 offset;
+	float4 color;
+	int object_type;
+};
+[[vk::push_constant]] PushConstants push_constants;
+
+FSOutput main(VSOutput input)
+{
+	FSOutput output = (FSOutput)0;
+	float4 color;
+
+	switch (push_constants.object_type) {
+		case 0: // Skysphere
+			{
+				color = textureEnvMap.Sample(samplerEnvMap, float2(input.UV.x, 1.0 - input.UV.y));
+			}
+			break;
+
+		case 1: // Phong shading
+			{
+				float3 ambient = push_constants.color.rgb * 0.5;
+				float3 N = normalize(input.Normal);
+				float3 L = normalize(input.LightVec);
+				float3 V = normalize(input.ViewVec);
+				float3 R = reflect(-L, N);
+				float3 diffuse = max(dot(N, L), 0.0).xxx * push_constants.color.rgb;
+				float3 specular = (pow(max(dot(R, V), 0.0), 8.0)).xxx;
+				color = float4(ambient + diffuse + specular, 1.0);
+			}
+			break;
+	}
+
+	// Base color into attachment 0
+	output.Color0 = float4(color.rgb, 1.0);
+
+	// Bright parts for bloom into attachment 1
+	float l = dot(output.Color0.rgb, float3(0.2126, 0.7152, 0.0722));
+	float threshold = 0.75;
+	output.Color1.rgb = (l > threshold) ? output.Color0.rgb : float3(0.0, 0.0, 0.0);
+	output.Color1.a = 1.0;
+	return output;
+}
@@ -0,0 +1,74 @@
+/* Copyright (c) 2024, Sascha Willems
+ *
+ * SPDX-License-Identifier: Apache-2.0
+ *
+ * Licensed under the Apache License, Version 2.0 the "License";
+ * you may not use this file except in compliance with the License.
+ * You may obtain a copy of the License at
+ *
+ *     http://www.apache.org/licenses/LICENSE-2.0
+ *
+ * Unless required by applicable law or agreed to in writing, software
+ * distributed under the License is distributed on an "AS IS" BASIS,
+ * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+ * See the License for the specific language governing permissions and
+ * limitations under the License.
+ */
+
+struct VSInput
+{
+[[vk::location(0)]] float3 Pos : POSITION0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float2 UV : TEXCOORD0;
+};
+
+struct UBO  {
+	float4x4 projection;
+	float4x4 modelview;
+    float4x4 skyboxModelview;
+    float modelscale;
+};
+[[vk::binding(0, 0)]]
+ConstantBuffer<UBO> ubo : register(b0);
+
+struct VSOutput
+{
+	float4 Pos : SV_POSITION;
+[[vk::location(0)]] float2 UV : TEXCOORD0;
+[[vk::location(1)]] float3 Normal : NORMAL0;
+[[vk::location(2)]] float3 ViewVec : TEXCOORD1;
+[[vk::location(3)]] float3 LightVec : TEXCOORD2;
+};
+
+struct PushConstants
+{
+	float4 offset;
+	float4 color;
+	int object_type;
+};
+[[vk::push_constant]] PushConstants push_constants;
+
+VSOutput main(VSInput input)
+{
+	VSOutput output = (VSOutput)0;
+    float3 worldPos;
+
+	switch(push_constants.object_type) {
+		case 0: // Skybox
+            worldPos = mul((float4x3) ubo.skyboxModelview, input.Pos).xyz;
+			output.Pos = mul(ubo.projection, float4(worldPos, 1.0));
+			break;
+		case 1: // Object
+			float3 localPos = input.Pos * ubo.modelscale + push_constants.offset.xyz;
+            worldPos = mul(ubo.modelview, float4(localPos, 1.0)).xyz;
+            output.Pos = mul(ubo.projection, mul(ubo.modelview, float4(localPos, 1.0)));
+			break;
+	}
+	output.Normal = mul((float4x3)ubo.modelview, input.Normal).xyz;
+	output.UV = input.UV;
+	
+	float3 lightPos = float3(0.0f, -5.0f, 5.0f);
+    output.LightVec = lightPos.xyz - worldPos.xyz;
+    output.ViewVec = -worldPos.xyz;
+	return output;
+}